Description

DescriptionChronogrammes loi trapezoidale en acceleration.svg	English: Chronograms for a movement with a trapezoidal acceleration law, in order to control the jerk. A body is moved from the position x = 0 to x = xf, the duration of the movement is T. There are three parts which last T/3: Acceleration (a > 0). Constant velocity (a = 0). Braking (a < 0). In the firts and third parts, a has a trapezoid shape (each subpart lasts T/9), with a maximum value of a0. Français : Chronogrammes pour un mouvement suivant une loi trapézoïdale en accélération, afin de maîtriser l'à-coup (jerk). Il y a trois partie d'une durée de T/3 : Accélération (a > 0). Mouvement uniforme (a = 0). Freinage (a < 0). Dans la première et la troisième partie, a a une forme trapézoïdale (chaque sous-partie durant T/9), avec une accélération maximale valant a0.
Date	13 février 2014
Source	Travail personnel
Auteur	Christophe Dang Ngoc Chan (Cdang )
SVG information InfoField	Le code de ce fichier SVG n'est pas valide en raison d'une erreur.   Cette figure géométrique W3C-invalide a été créée avec Batik, Scilab   Cette figure géométrique SVG utilise du texte encapsulé.

1.

${\displaystyle a={\frac {9a_{0}t}{\mathrm {T} }}}$

${\displaystyle v={\frac {9a_{0}t^{2}}{2\mathrm {T} }}}$

${\displaystyle x={\frac {3a_{0}t^{3}}{2\mathrm {T} }}}$

${\displaystyle a_{1}=a_{0}}$

${\displaystyle v_{1}={\frac {a_{0}\mathrm {T} }{18}}={\frac {a_{0}\mathrm {T} }{2\times 3^{2}}}\simeq 0,055\,6a_{0}\mathrm {T} }$

${\displaystyle x_{1}={\frac {a_{0}\mathrm {T} ^{2}}{486}}={\frac {a_{0}\mathrm {T} ^{2}}{2\times 3^{5}}}\simeq 0,002\,06a_{0}\mathrm {T} ^{2}}$

2.

${\displaystyle a=a_{0}}$

${\displaystyle v=v_{1}+a_{0}\left(t-{\frac {\mathrm {T} }{9}}\right)=a_{0}\left(t-{\frac {\mathrm {T} }{18}}\right)}$

${\displaystyle x=a_{0}\left({\frac {t^{2}}{2}}-{\frac {\mathrm {T} t}{18}}+{\frac {\mathrm {T} ^{2}}{486}}\right)}$

${\displaystyle a_{2}=a_{0}}$

${\displaystyle v_{2}={\frac {a_{0}\mathrm {T} }{6}}={\frac {a_{0}\mathrm {T} }{2\times 3}}\simeq 0,167a_{0}\mathrm {T} }$

${\displaystyle x_{2}={\frac {7a_{0}\mathrm {T} ^{2}}{486}}={\frac {7a_{0}\mathrm {T} ^{2}}{2\times 3^{5}}}\simeq 0,014\,4a_{0}\mathrm {T} ^{2}}$

3.

${\displaystyle a=a_{0}\left(-{\frac {9t}{\mathrm {T} }}+3\right)}$

${\displaystyle v=a_{0}\left(-{\frac {9t^{2}}{2\mathrm {T} }}+3t-{\frac {\mathrm {5T} }{18}}\right)}$

${\displaystyle x=a_{0}\left({\frac {-3t^{3}}{2\mathrm {T} }}+{\frac {3t^{2}}{2}}-{\frac {5\mathrm {T} t}{18}}+{\frac {\mathrm {T} ^{2}}{54}}\right)}$

${\displaystyle a_{3}=0}$

${\displaystyle v_{3}={\frac {2a_{0}\mathrm {T} }{9}}={\frac {2a_{0}\mathrm {T} }{3^{2}}}\simeq 0,222a_{0}\mathrm {T} }$

${\displaystyle x_{3}={\frac {a_{0}\mathrm {T} ^{2}}{27}}={\frac {a_{0}\mathrm {T} ^{2}}{3^{3}}}\simeq 0,037\,0a_{0}\mathrm {T} ^{2}}$

4.

${\displaystyle a=0}$

${\displaystyle v=v_{3}}$

${\displaystyle x=x_{3}+v_{3}\left(t-{\frac {\mathrm {T} }{3}}\right)={\frac {a_{0}\mathrm {T} }{9}}\left(2t-{\frac {\mathrm {T} }{3}}\right)}$

${\displaystyle a_{4}=0}$

${\displaystyle v_{4}=v_{3}}$

${\displaystyle x_{4}={\frac {a_{0}\mathrm {T} ^{2}}{9}}={\frac {a_{0}\mathrm {T} ^{2}}{3^{2}}}\simeq 0,111a_{0}\mathrm {T} ^{2}}$

5.

${\displaystyle a=-{\frac {9a_{0}}{\mathrm {T} }}\left(t-{\frac {2\mathrm {T} }{3}}\right)=a_{0}\left({\frac {-9t}{\mathrm {T} }}+6\right)}$

${\displaystyle v=a_{0}\left({\frac {-9t^{2}}{2\mathrm {T} }}+6t-{\frac {16\mathrm {T} }{9}}\right)}$

${\displaystyle x=a_{0}\left(-{\frac {3t^{3}}{2\mathrm {T} }}+3t^{2}-{\frac {16\mathrm {T} t}{9}}+{\frac {11\mathrm {T} ^{2}}{27}}\right)}$

${\displaystyle a_{5}=-a_{0}}$

${\displaystyle v_{5}=v_{2}}$

${\displaystyle x_{5}={\frac {65a_{0}\mathrm {T} ^{2}}{486}}={\frac {13\times 5a_{0}\mathrm {T} ^{2}}{2\times 3^{5}}}\simeq 0,134a_{0}\mathrm {T} ^{2}}$

6.

${\displaystyle a=-a_{0}}$

${\displaystyle v=a_{0}\left(-t+{\frac {17\mathrm {T} }{18}}\right)}$

${\displaystyle x=a_{0}\left({\frac {-t^{2}}{2}}+{\frac {17\mathrm {T} t}{18}}-{\frac {145\mathrm {T} ^{2}}{486}}\right)}$

${\displaystyle a_{6}=-a_{0}}$

${\displaystyle v_{6}=v_{1}}$

${\displaystyle x_{6}={\frac {71a_{0}\mathrm {T} ^{2}}{486}}={\frac {71a_{0}\mathrm {T} ^{2}}{2\times 3^{5}}}\simeq 0,146a_{0}\mathrm {T} ^{2}}$

7.

${\displaystyle a=a_{0}\left({\frac {9t}{\mathrm {T} }}-9\right)}$

${\displaystyle v=a_{0}\left({\frac {9t^{2}}{2\mathrm {T} }}-9t+{\frac {9\mathrm {T} }{2}}\right)}$

${\displaystyle x=a_{0}\left({\frac {3t^{3}}{2\mathrm {T} }}-{\frac {9t^{2}}{2}}+{\frac {9\mathrm {T} t}{2}}-{\frac {73\mathrm {T} ^{2}}{54}}\right)}$

${\displaystyle a_{7}=0}$

${\displaystyle v_{7}=0}$

${\displaystyle x_{\mathrm {f} }={\frac {4a_{0}\mathrm {T} ^{2}}{27}}={\frac {2^{2}\times a_{0}\mathrm {T} ^{2}}{3^{3}}}\simeq 0,148a_{0}\mathrm {T} ^{2}}$

Max.

${\displaystyle v_{\max }={\frac {2a_{0}\mathrm {T} }{9}}={\frac {3x_{\mathrm {f} }}{2\mathrm {T} }}}$

${\displaystyle a_{\max }=a_{0}={\frac {27x_{\mathrm {f} }}{4\mathrm {T} ^{2}}}}$

${\displaystyle j_{\max }={\frac {9a_{0}}{\mathrm {T} }}={\frac {243x_{\mathrm {f} }}{4\mathrm {T} ^{3}}}}$

Scilab source

This media was created with Scilab, a free open-source software. Here is a listing of the Scilab source used to create this file.

function [t1, t2, t3, t4, t5, t6, t7] = indice(t)
    t1 = (t < 1/9);
    t2 = (t >= 1/9) & (t < 2/9);
    t3 = (t >= 2/9) & (t < 1/3);
    t4 = (t >= 1/3) & (t <= 2/3);
    t5 = (t > 2/3) & (t <= 7/9);
    t6 = (t > 7/9) & (t <=8/9);
    t7 = (t > 8/9);
endfunction

function [j]=jerk(t)
    [t1, t2, t3, t4, t5, t6, t7] = indice(t);
    j = zeros(t);
    j(t1) = 9;
    j(t2) = 0;
    j(t3) = -9;
    j(t4) = 0;
    j(t5) = -9;
    j(t6) = 0;
    j(t7) = 9;
endfunction

function [a]=acceleration(t)
    [t1, t2, t3, t4, t5, t6, t7] = indice(t);
    a = zeros(t);
    a(t1) = 9*t(t1);
    a(t2) = 1;
    a(t3) = (3 - 9*t(t3));
    a(t4) = 0;
    a(t5) = 6 - 9*t(t5);
    a(t6) = -1;
    a(t7) = 9*t(t7) - 9;
endfunction

function [v] = vitesse(t)
    [t1, t2, t3, t4, t5, t6, t7] = indice(t);
    v = zeros(t);
    v(t1) = 9/2*t(t1).^2;
    v(t2) = t(t2) - 1/18;
    v(t3) = (-9/2*t(t3) + 3).*t(t3) - 5/18;
    v(t4) = 2/9;
    v(t5) = (-9/2*t(t5) + 6).*t(t5) - 16/9;
    v(t6) = -t(t6) + 17/18;
    v(t7) = (9/2*t(t7) - 9).*t(t7) + 9/2;
endfunction

function [x] = position(t)
    [t1, t2, t3, t4, t5, t6, t7] = indice(t);
    x = zeros(t);
    x(t1) = 3/2*t(t1).^3;
    x(t2) = (0.5*t(t2) - 1/18).*t(t2) + 1/486;
    x(t3) = ((-3/2*t(t3) + 3/2).*t(t3) - 5/18).*t(t3) + 1/54;
    x(t4) = 1/9*(2*t(t4) - 1/3);
    x(t5) = ((-3/2*t(t5) + 3).*t(t5) - 16/9).*t(t5) + 11/27;
    x(t6) = (-0.5*t(t6) + 17/18).*t(t6) - 145/486;
    x(t7) = ((3/2*t(t7) - 9/2).*t(t7) + 9/2).*t(t7) - 73/54;
endfunction

t = 0:0.005:1;

j = jerk(t);
a = acceleration(t);
v = vitesse(t);
x = position(t);

scf(0);
clf;

subplot(4, 1, 1)
plot(t, x)
xtitle("position", "t/T", "$x/(a_0 \mathrm{T}^2)$")

subplot(4, 1, 2)
plot(t, v)
xtitle("vitesse", "t/T", "$v/(a_0 \mathrm{T})$")

subplot(4, 1, 3)
plot(t, a)
xtitle("accélération", "t/T", "$a/a_0$")

subplot(4, 1, 4)
xtitle("à-coup", "t/T", "$j \times \mathrm{T}/a_0$")
plot(t, j)

Conditions d’utilisation

Moi, en tant que détenteur des droits d’auteur sur cette œuvre, je la publie sous les licences suivantes :

Vous avez la permission de copier, distribuer et modifier ce document selon les termes de la GNU Free Documentation License version 1.2 ou toute version ultérieure publiée par la Free Software Foundation, sans sections inaltérables, sans texte de première page de couverture et sans texte de dernière page de couverture. Un exemplaire de la licence est inclus dans la section intitulée GNU Free Documentation License.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

Ce fichier est sous licence Creative Commons Attribution – Partage dans les Mêmes Conditions 3.0 (non transposée), 2.5 Générique, 2.0 Générique et 1.0 Générique.

Vous êtes libre :

• de partager – de copier, distribuer et transmettre cette œuvre
• d’adapter – de modifier cette œuvre

Sous les conditions suivantes :

• paternité – Vous devez donner les informations appropriées concernant l'auteur, fournir un lien vers la licence et indiquer si des modifications ont été faites. Vous pouvez faire cela par tout moyen raisonnable, mais en aucune façon suggérant que l’auteur vous soutient ou approuve l’utilisation que vous en faites.
• partage à l’identique – Si vous modifiez, transformez, ou vous basez sur cette œuvre, vous devez distribuer votre contribution sous la même licence ou une licence compatible avec celle de l’original.

https://creativecommons.org/licenses/by-sa/3.0CC BY-SA 3.0 Creative Commons Attribution-Share Alike 3.0 truetrue

Vous pouvez choisir l’une de ces licences.