Description

(*Source code written in Mathematica 6.0 by Steve Byrnes, Apr. 2011.
  This source code is public domain.*)
  
(*Shows classical and quantum trajectory animations for an infinite-square-well potential.
  Assumes L=hbar=1, m=2*pi^(-2), so that the nth energy eigenstate has energy n^2.*)

ClearAll["Global`*"]

(***Wavefunctions of the energy eigenstates***)
psi[n_, x_] := Sin[n*Pi*x]*2^(1/2);
energy[n_] := n^2;
psit[n_, x_, t_] := psi[n, x] Exp[-I*energy[n]*t];

(***A random time-dependent state***)
SeedRandom[1];
CoefList = Table[Random[]*Exp[2*Pi*I*Random[]], {n, 1, 4}];
CoefList = CoefList/Norm[CoefList];
Randpsi[x_, t_] := Sum[CoefList[[n]]*psit[n, x, t], {n, 1, 4}];

(***Another random time-dependent state***)
SeedRandom[2];
CoefList2 = Table[Random[]*Exp[2*Pi*I*Random[]], {n, 1, 3}];
CoefList2 = CoefList2/Norm[CoefList2];
Randpsi2[x_, t_] := Sum[CoefList2[[n]]*psit[n, x, t], {n, 1, 3}];

(***Set default style for plots***)
SetOptions[Plot,
  {PlotRange -> {{-.05, 1.05}, {-2.5, 2.5}}, Ticks -> None, 
   PlotStyle -> {Directive[Thick, Blue], Directive[Thick, Pink]}, 
   Axes -> {True, False}}];
SetOptions[ListPlot, {PlotRange -> {{-.05, 1.05}, {-2.5, 2.5}}, Axes -> False}];

(***Draw walls***)
walls = ListPlot[{{{0, -2.5}, {0, 2.5}}, {{1, -2.5}, {1, 2.5}}}, 
   Joined -> True, PlotStyle -> {{Thick, Black}, {Thick, Black}}];

(***Make the classical plot...a red ball bounces back and forth.***)
classicaltrajectory[t_, left_, right_] := 2*(right - left)*Abs[t - Round[t]] + left;
classicalball[t_, left_, right_] := ListPlot[{{classicaltrajectory[t, left, right], 0}},
   PlotStyle -> Directive[Red, AbsolutePointSize[15]]];
classical[t_, label_] := Show[walls, classicalball[t, .1, .9], PlotLabel -> label];
(***Make the quantum plots***)
plotpsi[n_, t_, label_] := Show[walls,
   Plot[{Re[psit[n, x, t]], Im[psit[n, x, t]]}, {x, 0, 1}],
   PlotLabel -> label, Axes -> {True, False}, Ticks -> None];
plotrand[t_, label_] := Show[walls,
   Plot[{Re[Randpsi[x, t]], Im[Randpsi[x, t]]}, {x, 0, 1}],
   PlotLabel -> label, Axes -> {True, False}, Ticks -> None];
plotrand2[t_, label_] := Show[walls, 
   Plot[{Re[Randpsi2[x, t]], Im[Randpsi2[x, t]]}, {x, 0, 1}], 
   PlotLabel -> label, Axes -> {True, False}, Ticks -> None];
(***Put all the plots together***)
MakeFrame[t_] := GraphicsGrid[
   {{classical[3 t/(4 Pi), "A"], plotpsi[1, t, "B"]},
    {plotpsi[2, t, "C"], plotpsi[3, t, "D"]},
    {plotrand[t, "E"], plotrand2[t, "F"]}},
   Frame -> All, ImageSize -> 300];
output = Table[MakeFrame[t], {t, 0, 4 Pi*138/139, 4 Pi/139}];
SetDirectory["C:\\Users\\Steve\\Desktop"]
Export["test.gif", output, "DisplayDurations" -> 10]

Conditions d’utilisation

Moi, en tant que détenteur des droits d’auteur sur cette œuvre, je la publie sous la licence suivante :

Ce fichier est disponible selon les termes de la licence Creative Commons CC0 Don universel au domaine public.

La personne qui a associé une œuvre avec cet acte l’a placée dans le domaine public en renonçant mondialement à tous ses droits sur cette œuvre en vertu des lois relatives au droit d’auteur, ainsi qu’à tous les droits juridiques connexes et voisins qu’elle possédait sur l’œuvre, sans autre limite que celles imposées par la loi. Vous pouvez copier, modifier, distribuer et utiliser cette œuvre, y compris à des fins commerciales, sans qu’il soit nécessaire d’en demander la permission. http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse